alsa-lib/configure.in

dnl Process this file with autoconf to produce a configure script.
AC_INIT(src/control/control.c)
dnl *************************************************
dnl current:revision:age
dnl change (without API) = c:r+1:a
dnl change API = c+1:0:a
dnl add API = c+1:0:a+1
dnl remove API = c+1:0:0
dnl *************************************************
AM_INIT_AUTOMAKE(alsa-lib, 0.9.0beta6)
eval LIBTOOL_VERSION_INFO="2:0:0"
dnl *************************************************
AM_CONDITIONAL(INSTALL_M4, test "x${ACLOCAL}" = "xaclocal")

AC_PREFIX_DEFAULT(/usr)

dnl Checks for programs.
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S 
AM_PROG_LIBTOOL

dnl path for linux/asound.h
AC_ARG_WITH(kernel,
  [  --with-kernel=dir       give the directory with kernel sources (optional)],
  [kerneldir="$withval"], [kerneldir=""])
if test "$kerneldir" != "" -a -d $kerneldir/include ; then
  ALSA_CFLAGS="$ALSA_CFLAGS -I$kerneldir/include"
  CFLAGS="$CFLAGS -I$kerneldir/include"
fi
AC_MSG_RESULT($ALSA_CFLAGS)

dnl Check for asound.h localtion
ASOUND_PATH=""
if test x"$kerneldir" != x""; then
  if test -f $kerneldir/include/sound/asound.h; then
    ASOUND_PATH=$kerneldir/include/sound
  fi
fi
if test x$asound_loc = x ; then
  if test -f /usr/include/sound/asound.h; then
    ASOUND_PATH=/usr/include/sound
  else
    ASOUND_PATH=../../alsa-driver/include
  fi
fi
AC_SUBST(ASOUND_PATH)
    
dnl Checks for header files.
AC_HEADER_STDC
AM_CONFIG_HEADER(include/config.h)
# AC_CHECK_HEADERS(linux/asound.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_HEADER_TIME

dnl Checks for library functions.
AC_PROG_GCC_TRADITIONAL
AC_CHECK_FUNC([hsearch_r], [HAVE_HSEARCH_R=yes])
AM_CONDITIONAL(ALSA_HSEARCH_R, [test "x$HAVE_HSEARCH_R" != xyes])

ALSA_CHECK_DRIVER
SAVE_LIBRARY_VERSION
AC_SUBST(LIBTOOL_VERSION_INFO)

test "x$prefix" = xNONE && prefix=$ac_default_prefix

eval dir="$datadir"
case "$dir" in
/*) ;;
*) dir="$PWD/$dir"
esac
AC_DEFINE_UNQUOTED(DATADIR, "$dir")

AC_OUTPUT(Makefile doc/Makefile include/Makefile src/Makefile \
          src/control/Makefile src/mixer/Makefile src/pcm/Makefile \
	  src/rawmidi/Makefile src/timer/Makefile \
          src/hwdep/Makefile src/seq/Makefile src/instr/Makefile \
          src/compat/Makefile src/conf/Makefile \
	  src/conf/cards/Makefile src/conf/pcm/Makefile \
	  aserver/Makefile test/Makefile utils/Makefile \
          utils/alsa-lib.spec doc/doxygen.cfg)